root / framework / tags / fusebox5A2 / fuseboxWriter.cfc

<!---
Fusebox Software License
Version 1.0

Copyright (c) 2003, 2004, 2005, 2006 The Fusebox Corporation. All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted 
provided that the following conditions are met:

1. Redistributions of source code must retain the above copyright notice, this list of conditions 
   and the following disclaimer.

2. Redistributions in binary form or otherwise encrypted form must reproduce the above copyright 
   notice, this list of conditions and the following disclaimer in the documentation and/or other 
   materials provided with the distribution.

3. The end-user documentation included with the redistribution, if any, must include the following 
   acknowledgment:

   "This product includes software developed by the Fusebox Corporation (http://www.fusebox.org/)."

   Alternately, this acknowledgment may appear in the software itself, if and wherever such 
   third-party acknowledgments normally appear.

4. The names "Fusebox" and "Fusebox Corporation" must not be used to endorse or promote products 
   derived from this software without prior written (non-electronic) permission. For written 
   permission, please contact fusebox@fusebox.org.

5. Products derived from this software may not be called "Fusebox", nor may "Fusebox" appear in 
   their name, without prior written (non-electronic) permission of the Fusebox Corporation. For 
   written permission, please contact fusebox@fusebox.org.

If one or more of the above conditions are violated, then this license is immediately revoked and 
can be re-instated only upon prior written authorization of the Fusebox Corporation.

THIS SOFTWARE IS PROVIDED "AS IS" AND ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE 
DISCLAIMED. IN NO EVENT SHALL THE FUSEBOX CORPORATION OR ITS CONTRIBUTORS BE LIABLE FOR ANY 
DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT 
LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR 
BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, 
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE 
OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

-------------------------------------------------------------------------------

This software consists of voluntary contributions made by many individuals on behalf of the 
Fusebox Corporation. For more information on Fusebox, please see <http://www.fusebox.org/>.

--->
<cfcomponent output="false">

        <cffunction name="init" returntype="fuseboxWriter" access="public" output="false">
                <cfargument name="fbApp" type="fuseboxApplication" required="true" />
                
                <cfset variables.parsedDir = arguments.fbApp.getApplicationRoot() & arguments.fbApp.parsePath />
                <cfset variables.phase = "" />
                <cfset variables.circuit = "" />
                <cfset variables.fuseaction = "" />
                <cfset variables.newline = chr(13) & chr(10) />
                
                <cfif not directoryExists(variables.parsedDir)>
                        <cflock name="#variables.parsedDir#" type="exclusive" timeout="30">
                                <cfif not directoryExists(variables.parsedDir)>
                                        <cftry>
                                                <cfdirectory action="create" directory="#variables.parsedDir#" mode="777" />
                                        <cfcatch>
                                                <cfthrow type="fusebox.missingParsedDirException"
                                                        message="The 'parsed' directory in the application root directory is missing, and could not be created"
                                                        detail="You must manually create this directory, and ensure that CF has the ability to write and change files within the directory." />
                                        </cfcatch>
                                        </cftry>
                                </cfif>
                        </cflock>
                </cfif>

                <cfset reset() />

                <cfreturn this />

        </cffunction>

        <cffunction name="reset" returntype="void" access="public" output="false">

                <cfset variables.lastPhase = "" />
                <cfset variables.lastCircuit = "" />
                <cfset variables.lastFuseaction = "" />
                <cfset variables.content = "" />

        </cffunction>   

        <cffunction name="open" returntype="void" access="public" output="false">
                <cfargument name="filename" type="string" required="true" />
                
                <cfset variables.filename = arguments.filename />
                <cfset reset() />
                <cfset rawPrintln('<cfsetting enablecfoutputonly="true" />') />
                <cfset rawPrintln('<cfprocessingdirective pageencoding="utf-8" />') />
                
        </cffunction>
        
        <cffunction name="close" returntype="void" access="public" output="false">
                
                <cfset rawPrintln('<cfsetting enablecfoutputonly="false" />') />
                <cffile action="write" file="#variables.parsedDir#/#variables.filename#"
                                output="#variables.content#" charset="utf-8" />
                
        </cffunction>
        
        <cffunction name="setPhase" returntype="string" access="public" output="false">
                <cfargument name="phase" type="string" required="true" />
                
                <cfset var p = variables.phase />
                
                <cfset variables.phase = arguments.phase />
                
                <cfreturn p />
                
        </cffunction>
        
        <cffunction name="setCircuit" returntype="string" access="public" output="false">
                <cfargument name="circuit" type="string" required="true" />
                
                <cfset var c = variables.circuit />
                
                <cfset variables.circuit = arguments.circuit />
                
                <cfreturn c />
                
        </cffunction>
        
        <cffunction name="setFuseaction" returntype="string" access="public" output="false">
                <cfargument name="fuseaction" type="string" required="true" />
                
                <cfset var f = variables.fuseaction />
                
                <cfset variables.fuseaction = arguments.fuseaction />
                
                <cfreturn f />
                
        </cffunction>
        
        <cffunction name="print" returntype="void" access="public" output="false">
                <cfargument name="text" type="string" required="true" />
                
                <cfif variables.lastPhase is not variables.phase>
                        <cfset rawPrintln('<cfset myFusebox.thisPhase = "#variables.phase#">') />
                        <cfset variables.lastPhase = variables.phase />
                </cfif>
                <cfif variables.lastCircuit is not variables.circuit>
                        <cfset rawPrintln('<cfset myFusebox.thisCircuit = "#variables.circuit#">') />
                        <cfset variables.lastCircuit = variables.circuit />
                </cfif>
                <cfif variables.lastFuseaction is not variables.fuseaction>
                        <cfset rawPrintln('<cfset myFusebox.thisFuseaction = "#variables.fuseaction#">') />
                        <cfset variables.lastFuseaction = variables.fuseaction />
                </cfif>
                <cfset rawPrint(arguments.text) />
                
        </cffunction>
        
        <cffunction name="println" returntype="void" access="public" output="false">
                <cfargument name="text" type="string" required="true" />
                
                <cfset print(arguments.text) />
                <cfset variables.content = variables.content & variables.newline />
                
        </cffunction>
        
        <cffunction name="rawPrint" returntype="void" access="public" output="false">
                <cfargument name="text" type="string" required="true" />

                <cfset variables.content = variables.content & arguments.text />

        </cffunction>
        
        <cffunction name="rawPrintln" returntype="void" access="public" output="false">
                <cfargument name="text" type="string" required="true" />

                <cfset rawPrint(arguments.text) />
                <cfset variables.content = variables.content & variables.newline />

        </cffunction>
        
</cfcomponent>