root / framework / tags / fusebox5A2 / fusebox5.cfm

<cftry>
<cfsilent>
<!---
Fusebox Software License
Version 1.0

Copyright (c) 2003, 2004, 2005, 2006 The Fusebox Corporation. All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted 
provided that the following conditions are met:

1. Redistributions of source code must retain the above copyright notice, this list of conditions 
   and the following disclaimer.

2. Redistributions in binary form or otherwise encrypted form must reproduce the above copyright 
   notice, this list of conditions and the following disclaimer in the documentation and/or other 
   materials provided with the distribution.

3. The end-user documentation included with the redistribution, if any, must include the following 
   acknowledgment:

   "This product includes software developed by the Fusebox Corporation (http://www.fusebox.org/)."

   Alternately, this acknowledgment may appear in the software itself, if and wherever such 
   third-party acknowledgments normally appear.

4. The names "Fusebox" and "Fusebox Corporation" must not be used to endorse or promote products 
   derived from this software without prior written (non-electronic) permission. For written 
   permission, please contact fusebox@fusebox.org.

5. Products derived from this software may not be called "Fusebox", nor may "Fusebox" appear in 
   their name, without prior written (non-electronic) permission of the Fusebox Corporation. For 
   written permission, please contact fusebox@fusebox.org.

If one or more of the above conditions are violated, then this license is immediately revoked and 
can be re-instated only upon prior written authorization of the Fusebox Corporation.

THIS SOFTWARE IS PROVIDED "AS IS" AND ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 
LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE 
DISCLAIMED. IN NO EVENT SHALL THE FUSEBOX CORPORATION OR ITS CONTRIBUTORS BE LIABLE FOR ANY 
DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT 
LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR 
BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, 
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE 
OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

-------------------------------------------------------------------------------

This software consists of voluntary contributions made by many individuals on behalf of the 
Fusebox Corporation. For more information on Fusebox, please see <http://www.fusebox.org/>.

--->

<!--- FB5: allow "" default - FB41 required this variable: --->
<cfparam name="FUSEBOX_APPLICATION_PATH" type="string" default="" />
<!--- FB5: application key - FB41 always uses 'fusebox': --->
<cfparam name="FUSEBOX_APPLICATION_KEY" type="string" default="fusebox" />

<cfparam name="attributes" type="struct" default="#structNew()#" />
<cfset structAppend(attributes,URL,true) />
<cfset structAppend(attributes,form,true) />

<!--- FB5: myFusebox is an object but has FB41-compatible public properties --->
<cfset myFusebox = createObject("component","myFusebox").init(FUSEBOX_APPLICATION_KEY,attributes) />
<!--- FB5: indicates whether application was started on this request --->
<cfset myFusebox.applicationStart = false />
<!---
        complex condition allows FB5 to drop into a running FB41 site and force re-init because
        FB41 application.fusebox will not have compileRequest() method - this should make upgrades
        to FB5 easier!
--->
<cfif not structKeyExists(application,FUSEBOX_APPLICATION_KEY) or myFusebox.parameters.load>
        <cflock name="#application.ApplicationName#_fusebox_#FUSEBOX_APPLICATION_KEY#" type="exclusive" timeout="300">
                <cfif not structKeyExists(application,FUSEBOX_APPLICATION_KEY) or myFusebox.parameters.load
                                or not structKeyExists(application[FUSEBOX_APPLICATION_KEY],"compileRequest")
                                or not isCustomFunction(application[FUSEBOX_APPLICATION_KEY].compileRequest)>
                        <cfset application[FUSEBOX_APPLICATION_KEY] =
                                        createObject("component","fuseboxApplication")
                                                .init(FUSEBOX_APPLICATION_KEY,FUSEBOX_APPLICATION_PATH,myFusebox) />
                        <cfset _fba = application[FUSEBOX_APPLICATION_KEY] />
                        <cfif myFusebox.parameters.parseall>
                                <cfset _fba.compileAll(myFusebox) />
                        </cfif>
                        <cfparam name="attributes.#_fba.fuseactionVariable#" default="#_fba.defaultFuseaction#" />
                        <cfset myFusebox.applicationStart = true />
                        <!--- force parse after reload for consistency --->
                        <cfset myFusebox.parameters.parse = true />
                        <!--- FB5: new appinit include file --->
                        <cftry>
                                <cfinclude template="#_fba.getCoreToAppRootPath()#fusebox.appinit.cfm" />
                        <cfcatch type="missinginclude" />
                        </cftry>
                <cfelse>
                        <cfset _fba = application[FUSEBOX_APPLICATION_KEY] />
                        <cfparam name="attributes.#_fba.fuseactionVariable#" default="#_fba.defaultFuseaction#" />
                </cfif>
        </cflock>
<cfelse>
        <cfset _fba = application[FUSEBOX_APPLICATION_KEY] />
        <cfparam name="attributes.#_fba.fuseactionVariable#" default="#_fba.defaultFuseaction#" />
</cfif>
<cftry>
        <cfinclude template="#_fba.getCoreToAppRootPath()#fusebox.init.cfm" />
<cfcatch type="missinginclude" />
</cftry>
<cfset _parsedFile = _fba.compileRequest(attributes[_fba.fuseactionVariable],myFusebox) />
</cfsilent><cfprocessingdirective suppresswhitespace="true">
<cfinclude template="#_parsedFile#" />
</cfprocessingdirective>
<cfcatch type="fusebox">
        <cfif not isDefined("_fba.errortemplatesPath") or not _fba.handleFuseboxException(cfcatch)>
                <cfrethrow /> 
        </cfif>
</cfcatch>
</cftry>