root / framework / branches / dev / fuseboxControllerMethod.cfc

<!---
Copyright 2006 TeraTech, Inc. http://teratech.com/

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
--->
<cfcomponent output="false" 
                        hint="I represent a fuseaction as a method within a controller CFC or a controller within an implicit circuit.">

        <cffunction name="init" returntype="any" access="public" output="false" 
                                hint="I am the constructor.">
                <cfargument name="circuit" type="any" required="false" 
                                        hint="I am the circuit to which this fuseaction belongs. I am required but it's faster to specify that I am not required." />
                <cfargument name="dottedPath" type="string" required="false" 
                                        hint="I am the dotted path to the CFC. I am required but it's faster to specify that I am not required." />
                <cfargument name="name" type="any" required="false" 
                                        hint="I am the name of the fuseaction. I am required but it's faster to specify that I am not required." />
                <cfargument name="fuseactionIsMethod" type="any" required="false"
                                        hint="I indicate whether the fuseaction is method (or a controller). I am required but it's faster to specify that I am not required." />
                
                <cfset variables.circuit = arguments.circuit />
                <cfset variables.dottedPath = arguments.dottedPath />
                <cfset variables.name = arguments.name />
                <cfset variables.fuseactionIsMethod = arguments.fuseactionIsMethod />
                
                <!--- implicit circuit fuseactions are public by default --->
                <cfset this.access = "public" />
                <cfset this.permissions = "" />
                
                <cfreturn this />
                
        </cffunction>
        
        <cffunction name="compile" returntype="void" access="public" output="false" 
                                hint="I compile this fuseaction.">
                <cfargument name="writer" type="any" required="false" 
                                        hint="I am the writer object to which the compiled code should be written. I am required but it's faster to specify that I am not required." />
        
                <cfif variables.fuseactionIsMethod>
                        <!--- TODO: if this throw Expression (Variable #uCase(getName())# is undefined.) then it was a missing fuseaction --->
                        <cfset arguments.writer.println('<cfinvoke component="#variables.dottedPath#" method="#getName()#">') />
                        <cfset arguments.writer.println('<cfinvokeargument name="myFusebox" value="##myFusebox##"/>') />
                        <cfset arguments.writer.println('<cfinvokeargument name="event" value="##event##" />') />
                        <cfset arguments.writer.println('</cfinvoke>') />
                <cfelse>
                        <!--- TODO: if this throw Expression (Variable #uCase(do)# is undefined.) then it was a missing/malformed fuseaction --->
                        <cfset arguments.writer.println('<cfinvoke component="#variables.dottedPath#" method="do">') />
                        <cfset arguments.writer.println('<cfinvokeargument name="myFusebox" value="##myFusebox##"/>') />
                        <cfset arguments.writer.println('<cfinvokeargument name="event" value="##event##" />') />
                        <cfset arguments.writer.println('</cfinvoke>') />
                </cfif>

        </cffunction>
        
        <cffunction name="getName" returntype="string" access="public" output="false" 
                                hint="I return the name of the fuseaction.">
                
                <cfreturn variables.name />
                
        </cffunction>

        <cffunction name="getCircuit" returntype="any" access="public" output="false" 
                                hint="I return the enclosing circuit object.">
        
                <cfreturn variables.circuit />
        
        </cffunction>
        
        <cffunction name="getAccess" returntype="string" access="public" output="false" 
                                hint="I am a convenience method to return this fuseaction's access attribute value.">
        
                <cfreturn this.access />
        
        </cffunction>
        
        <cffunction name="getPermissions" returntype="string" access="public" output="false" 
                                hint="I return the aggregated permissions for this fuseaction.">
        
                <cfreturn this.permissions />
                
        </cffunction>
        
        <cffunction name="getCustomAttributes" returntype="struct" access="public" output="false" 
                                hint="I return the custom (namespace-qualified) attributes for this fuseaction tag.">
                <cfargument name="ns" type="string" required="true" 
                                        hint="I am the namespace prefix whose attributes should be returned." />
                
                <cfreturn structNew() />

        </cffunction>

</cfcomponent>